CHAVE DE ACESSO DA NFe

Private Function GERARCHAVEDEACESSO(sNFE As String, sSERIE As String) As Boolean
Dim sTEMP As String
Dim sDATA As String
Dim iI As Integer
Dim yC As Byte
Dim iKEY As Integer
Dim iINDEX As Integer
Dim iDV As Integer
    GERARCHAVEDEACESSO = False
    schaveacessoNFE = ""
    sCODIGONUMERICO = ""
    If ACHAIBGE(sestadoUSU, scidadeUSU, "Usuário") = False Then
        Exit Function
    End If
    sBOOKIBGE = rscIBGE.Bookmark
    'composição da chave
    'Código da UF do emitente (IBGE)
    schaveacessoNFE = "" & rscIBGE!UF
    'ano,mes de emissão(AAMM)
    sDATA = Format$(Date, "dd/mm/yyyy")
    schaveacessoNFE = schaveacessoNFE & Right$(sDATA, 2)
    schaveacessoNFE = schaveacessoNFE & Mid$(sDATA, 4, 2)
    'CNPJ do emitente (sem máscara)
    schaveacessoNFE = schaveacessoNFE & removeTUDO(scnpjUSU)
    ' modelo = 55
    schaveacessoNFE = schaveacessoNFE & "55"
    'Série com 3 digitos
    sSERIE = "000" & sSERIE
    sSERIE = Right$(sSERIE, 3)
    schaveacessoNFE = schaveacessoNFE & sSERIE
    'Número da NFe com 9 digitos
    sNFE = "000000000" & sNFE
    sNFE = Right$(sNFE, 9)
    schaveacessoNFE = schaveacessoNFE & sNFE
    'Forma de emissão 1=NORMAL 2=CONTIGENCIA
    schaveacessoNFE = schaveacessoNFE & "1"
    'Número aleatório gerado com 8 digitos
    Randomize
    For iI = 1 To 8
        iINDEX = (9 * Rnd())
        sTEMP = sTEMP & Trim(LTrim(RTrim(Str(Trim((iINDEX))))))
    Next iI
    sCODIGONUMERICO = sTEMP
    schaveacessoNFE = schaveacessoNFE & sCODIGONUMERICO
    'iDV Digito verificador (Módulo 11)
    yC = 2
    'faz um loop por cada número o mutiplicando-o pelos valores de yC
    For iI = Len(schaveacessoNFE) To 1 Step -1
        'verifica se o valor de yC for maior que nove passa o valor para 2
        If yC > 9 Then
            yC = 2
        End If
        'soma os valores mutiplicados
        iKEY = iKEY + (CInt(Mid$(schaveacessoNFE, iI, 1)) * yC)
        yC = yC + 1
    Next
    'obtem o Digito Verificador
    If (iKEY Mod 11) = 0 Or (iKEY Mod 11) = 1 Then
        iDV = 0
    Else
        iDV = 11 - (iKEY Mod 11)
    End If
    schaveacessoNFE = schaveacessoNFE & Trim(LTrim(RTrim(Str(Trim(iDV)))))
    GERARCHAVEDEACESSO = True
    Exit Function
End Function

VEJA SE RESOLVE.  CLARO TEM QUE SUBSTITUIR AS VARIÁVEIS.

//