Quem pode dar uma ajudinha ?

Preciso implementar uma msflexgrid colocando combo em várias células, tem como?

Valeu!

Fui!!!!!!!!

Colega tenho um código legal pra você veja

 

insira no coloque em seu projeto uma combo e uma flexgrid, no exemplo dei o nome a flex de FlxGd.

 

 

Option Explicit

 

Private Sub Form_Load()
    Dim x As Integer
    With FlxGd
        .ColAlignment(-1) = 1
        For x = 1 To .Cols - 1
           .TextMatrix(0, x) = "Col " + Str(x)
        Next
        For x = 1 To FlxGd.Rows - 1
           .TextMatrix(x, 0) = "Row " + Str(x)
        Next
        .Row = 1
        .Col = 1
        .CellBackColor = &HC0FFFF
    End With
    Combo1_Load
End Sub

 

Private Sub FlxGd_EnterCell()
    FlxGd.CellBackColor = &HC0FFFF
    FlxGd.Tag = ""
End Sub

 

Private Sub FlxGd_LeaveCell()
       FlxGd.CellBackColor = &H80000005
End Sub

 

Private Sub FlxGd_Click()
    If Combo1.Visible = True Then
      Combo1.Visible = False
      FlxGd.CellBackColor = &H80000005
    End If
        Combo1.Width = FlxGd.CellWidth
        Combo1.Left = FlxGd.CellLeft + FlxGd.Left
        Combo1.Top = FlxGd.CellTop + FlxGd.Top
        Combo1.Text = FlxGd.Text
        Combo1.Visible = True
End Sub

 

Private Sub Combo1_Click()
      FlxGd.Text = Combo1.Text
      Combo1.Visible = False
End Sub

 

Private Sub Combo1_Load()
    FlxGd.RowHeightMin = Combo1.Height
    Combo1.Visible = False
    Combo1.Width = FlxGd.CellWidth
    Combo1.AddItem "1"
    Combo1.AddItem "2"
    Combo1.AddItem "3"
End Sub
  
pronto faça um teste

Valeu Treze !

Um abração.