Retorna a parte doargumento dalinha de comando usada para iniciar o Microsoft Visual Basic
ou um programa executável desenvolvido com o Visual Basic.

Sintaxe

Command

Comentários

Quando o Visual Basic é iniciado a partir da linha de comando, qualquer parte da linha de
comando posterior a /cmd é passada para o programa como argumento de linha de comando.
No exemplo a seguir, cmdlineargs representa a informação do argumento retornada pela função Command.

VB /cmd cmdlineargs

Para os aplicativos desenvolvidos com o Visual Basic e compilados para um arquivo .exe,
a função Command retorna todos os argumentos que aparecerem depois do nome do
aplicativo na linha de comando. Por exemplo:

MyApp cmdlineargs

Para obter informações sobre como modificar os argumentos de linha de comando na interface
de usuário do aplicativo que você está usando, procure "argumentos de linha de comando" na Ajuda.

Exemplo da função Command

Este exemplo usa a função Command para obter os argumentos de linha de
comando em uma função que os retorna em uma Variant que contém uma matriz.

Function GetCommandLine(Optional MaxArgs)
   ' Declara as variáveis.
   Dim C, CmdLine, CmdLnLen, InArg, I, NumArgs
   'Verifica se MaxArgs foi fornecido.
   If IsMissing(MaxArgs) Then MaxArgs = 10
   'Cria matriz do tamanho correto.
   ReDim ArgArray(MaxArgs)
   NumArgs = 0: InArg = False
   'Obtém argumentos de linha de comando.
   CmdLine = Command()
   CmdLnLen = Len(CmdLine)
   'Percorre um caractere da linha de comando,
   'de cada vez.
   For I = 1 To CmdLnLen
      C = Mid(CmdLine, I, 1)
      'Verifica a presença de espaço ou tab.
      If (C <> " " And C <> vbTab) Then
         'Nenhum espaço ou tab.
         'Verifica se já está no argumento.
         If Not InArg Then
         'Novo argumento iniciado.
         'Verifica o excesso de argumentos.
            If NumArgs = MaxArgs Then Exit For
            NumArgs = NumArgs + 1
            InArg = True
         End If
         'Concatena caractere com argumento atual.
         ArgArray(NumArgs) = ArgArray(NumArgs) & C
      Else
         'Encontrado um espaço ou tab.
         'Configura o sinalizador InArg como False.
         InArg = False
      End If
   Next I
   'Redimensiona a matriz de modo a conter os argumentos.
   ReDim Preserve ArgArray(NumArgs)
   'Retorna a matriz no nome da função.
   GetCommandLine = ArgArray()
End Function

Roberto