USUÁRIO:      SENHA:        SALVAR LOGIN ?    Adicione o VBWEB na sua lista de favoritos   Fale conosco 

 

  Dicas

  Visual Basic    (Redes/Comunicações)

Título da Dica:  Como desbloquear um usuário de rede no Active Directory
Postada em 23/12/2003 por David Pomarico      Clique aqui para enviar email para o autor  dcpomarico@yahoo.com.br
** Para que a ferramenta funcione, é necessário que seja executada com um usuário 'logado' que tenha permissão para alterar as propriedades dos usuários do Domínio. **

OBS.: -Insira dois textbox de nomes:
        txt_username (será digitado o username)
        txt_nome (aparecerá o nome completo para conferência)
        -Insira um checkbox de nome chk_travada (se .Value = 1 significa que a conta está travada)
        -Insira um botao cmd_checar (após digitar o username e clicar neste botao, ele trará os dados do usuário digitado)
        - Insira um botao cmdOk (para dar um commit no AD)
        - Insira um botao cmdCancel (para dar um unload no form e sair)


Option Explicit
'Para  obter  acesso  aos  métodos  da  classe  (IADsUser),  referencie
'o  componente  (Active  DS  Type  Library)
Dim usr   As IADsUser
Private Sub chk_Travada_Click()
If chk_Travada.Value = 1 Then
   usr.IsAccountLocked = True
Else
   usr.IsAccountLocked = False
End If
End Sub

Private Sub cmd_checar_Click()
On Error GoTo Erro:
Set usr = GetObject("WinNT://DOMINIO/" & txt_username.Text)
If usr.IsAccountLocked = True Then
   chk_Travada.Value = 1
Else
   chk_Travada.Value = 0
End If
txt_nome.Text = usr.FullName
ProcExit:
  Exit Sub
Erro:
If Err.Number = -2147024843 Then
   MsgBox "Usuário não encontrado!", vbOKOnly + vbExclamation, "Usuário"
   txt_username.SetFocus
   Resume ProcExit
Else
   MsgBox "Erro número: " & Err.Number & Chr(13) & Chr(13) & "Descrição: " & Err.Description, vbOKOnly
   txt_username.Enabled = True
   cmdOK.Enabled = True
   cmdCancel.Enabled = True
   Resume ProcExit
End If
End Sub

Private Sub cmdCancel_Click()
Unload Me
End Sub

Private Sub cmdOK_Click()
On Error GoTo Err:
usr.SetInfo
MsgBox "O usuário " & txt_username.Text & " foi atualizado com sucesso!", vbOKOnly, "Sucesso"
Unload Me

ProcExit:
  Exit Sub
Err:
MsgBox "Erro número: " & Err.Number & Chr(13) & Chr(13) & "Descrição: " & Err.Description, vbOKOnly
txt_username.Enabled = True
cmdOK.Enabled = True
cmdCancel.Enabled = True
Resume ProcExit

End Sub
 


CyberWEB Network Ltda.    © Copyright 2000-2024   -   Todos os direitos reservados.
Powered by HostingZone - A melhor hospedagem para seu site
Topo da página