Trabalhando com Data


	Fórum
	Visual Basic

Responder

Voltar

Autor

Assunto: Trabalhando com Data

faustosantos

ARAXÁ
MG - BRASIL

ENUNCIADA !

Postada em 25/05/2010 08:30 hs

preciso fazer uma pesquisa de data a data tipo uma informa a data inicial e a final e depois aparece a consulta em msflexgrid

eu que montei este codigo baseado em apostila e pesquisa feitas na internet mas ele não fuciona , vc poderia por favor me ajudar ver o que esta acontecendo

a conexão é via ADO usando codigo que esta perfeitamente funcionado em um Add mudule o banco de dados é access 2000

Vocês poderiam analisar este codigo para mim e me ajudar idenficar o erro porque não funciona agradeço muito pela atenção

Simplismente não aparece nada informo as datas e clicko no botão pesquisa e não aparece nada no grid não da nenhum erro nada oque será

Private Sub cmdProcessar_Click()

Dim cnnComando As New ADODB.Command
Dim rsSelecao As New ADODB.Recordset

Screen.MousePointer = vbHourglass
With cnnComando
.ActiveConnection = cnnPDV
.CommandType = adCmdText
.CommandText = "SELECT * FROM SAIDA ORDER BY B5 = '" & txts1.Text & "'"
Set rsSelecao = .Execute

With rsSelecao
If .EOF And .BOF Then
If IsDate(txts1) = True And IsDate(txts2) = True Then

With grid7
.Row = .Rows - 1
.Rows = .Rows + 1

.TextMatrix(0, 0) = "Código"
.ColWidth(0) = 800
.TextMatrix(grid7.Row, 0) = rsSelecao!B1

.TextMatrix(0, 1) = "Produto"
.ColWidth(1) = 3500
.TextMatrix(grid7.Row, 1) = rsSelecao!B2

.TextMatrix(0, 2) = "Qt"
.ColWidth(2) = 800
.TextMatrix(grid7.Row, 2) = rsSelecao!B3

.TextMatrix(0, 3) = "N°Pedido"
.ColWidth(3) = 800
.TextMatrix(grid7.Row, 3) = rsSelecao!B4

.TextMatrix(0, 4) = "Data"
.ColWidth(4) = 1500
.TextMatrix(grid7.Row, 4) = Format(rsSelecao!B5, "##/##/####")

rsSelecao.MoveNext

If grid7.Rows - 1 > 0 Then
grid7.Row = 1
End If

End With
End If
End If
End With
End With

'Elimina o command e o recordset da memória:
Set rsSelecao = Nothing
Set cnnComando = Nothing
Screen.MousePointer = vbDefault
Exit Sub
End Sub

J.Carlos

PRESIDENTE PRUDENTE
SP - BRASIL

ENUNCIADA !

Postada em 25/05/2010 09:31 hs

.CommandText-"Select * from Saida where dtEvento>=#2010/05/28 00:00:00# and dtEvento < #2010/05/29 00:00:00# order by B5"
ou usando o seu txt:

.CommandText="Select * from Saida where dtEvento=#" & format(cdate(text1.text),"YYYY/MM/DD hh:mm:ss") & "# and dtEvento<#" & format(cdate(text1.text) + 1,"YYYY/MM/DD hh:mm:ss") & "# order by B5"

Ou Se vc não usa hora na data:

.CommandText="Select * from Saida where dtEvento=#" & format(cdate(text1.text),"YYYY/MM/DD") & "# and dtEvento<#" & format(cdate(text1.text) + 1,"YYYY/MM/DD") & "# order by B5"

O resto pra carregar no grid fica aí contigo.

Treze

SÃO VICENTE
SP - BRASIL

ENUNCIADA !

Postada em 26/05/2010 09:47 hs

bom vou postar a solução dada por mim memso, em outro site a qual resolveu a duvida do colega

é esta

Private Sub cmdProcessar_Click()

Dim cnnComando As New ADODB.Command
Dim rsSelecao As New ADODB.Recordset

Screen.MousePointer = vbHourglass
With cnnComando
.ActiveConnection = cnnPDV
.CommandType = adCmdText
.CommandText = "SELECT * FROM SAIDA WHERE B5 BETWEEN #" & Format(txtDataIni.Text,"mm/dd/yyyy") & "# AND #" & Format(txtDataFim.Text,"mm/dd/yyyy") & "#"
Set rsSelecao = .Execute
End With

With grid7
.Rows = 1
.FixedCols = 0
.FormatString = "Código|Produto|Qt|No Pedido|Data"
.ColWidth(0) = 800
.ColWidth(1) = 3500
.ColWidth(2) = 800
.ColWidth(3) = 800
.ColWidth(4) = 1500

With rsSelecao
Do While Not .EOF
.Rows = .Rows + 1
.TextMatrix(.Rows - 1, 0) = !B1
.TextMatrix(.Rows - 1, 1) = !B2
.TextMatrix(.Rows - 1, 2) = !B3
.TextMatrix(.Rows - 1, 3) = !B4
.TextMatrix(.RowS - 1, 4) = Format(!B5, "dd/mm/yyyy")

.MoveNext

Loop

End With
End With

'Elimina o command e o recordset da memória:
Set rsSelecao = Nothing
Set cnnComando = Nothing
Screen.MousePointer = vbDefault
Exit Sub
End Sub

Lamattina

ASSIS
SP - BRASIL

ENUNCIADA !

Postada em 19/08/2010 13:48 hs

Fausto: Como eu trabalho com MSFlexGrid também, resolvi testar no meu projeto. Fiz algumas modificações no qual funcionou corretamente:

Dim cnnComando As New ADODB.Command
Dim rsSelecao As New ADODB.Recordset

    With Me
        .Height = 8445
        .Width = 13290
        '.Left = (mdfPrincipal.ScaleHeight - Me.Height) / 2
        .Top = (mdfPrincipal.ScaleWidth - Me.Width) / 6
    End With

    Screen.MousePointer = vbHourglass

    With cnnComando
        .ActiveConnection = cnn
        .CommandType = adCmdText
        .CommandText = "Select * from Cliente Where Razao like '%" & txtRazao.Text & "%';"
        Set rsSelecao = .Execute
    End With

    With msfCPesquisa
        .Visible = True
        .Rows = 1
        .FixedCols = 0
        .FormatString = "Código|Cliente|Cep|Endereço|DDD|Telefone|Celular|Sit."
        .ColWidth(0) = 800
        .ColWidth(1) = 3800
        .ColWidth(2) = 1000
        .ColWidth(3) = 3300
        .ColWidth(4) = 800
        .ColWidth(5) = 1000
        .ColWidth(6) = 1000
        .ColWidth(7) = 800
    End With

    With rsSelecao
        Do While Not .EOF
        With msfCPesquisa
            .Rows = .Rows + 1
            .TextMatrix(.Rows - 1, 0) = rsSelecao!ID
            .TextMatrix(.Rows - 1, 1) = rsSelecao!Razao
            .TextMatrix(.Rows - 1, 2) = rsSelecao!Cep
            .TextMatrix(.Rows - 1, 3) = rsSelecao!Endereco
            .TextMatrix(.Rows - 1, 4) = rsSelecao!DDD
            .TextMatrix(.Rows - 1, 5) = rsSelecao!Telefone
            .TextMatrix(.Rows - 1, 6) = rsSelecao!Celular
            .TextMatrix(.Rows - 1, 7) = rsSelecao!Sit
        End With
        .MoveNext
        Loop
    End With

    'Elimina o command e o recordset da memória:
    Set rsSelecao = Nothing
    Set cnnComando = Nothing
    Screen.MousePointer = vbDefault
    Exit Sub

Eduardo Lamattina

Jkarlosra

MACEIO
AL - BRASIL

ENUNCIADA !

Postada em 05/10/2010 15:37 hs

set regdata=cn.execute("SELECT * FROM SAIDA WHERE B5 BETWEEN #" & Format(txtDataIni.Text,"dd/mm/yyyy") & "# AND #" & Format(txtDataFim.Text,"dd/mm/yyyy") & "#")

vilmarbr

SAO PAULO
SP - BRASIL

ENUNCIADA !

Postada em 05/10/2010 16:11 hs

Se o banco de dados for Access tem que usar "#" & variavel_com_valor_datetime & "#" !

Se o banco de dados for SQLServer, Sybase tem que usar "'" & variavel_com_valor_datetime & "'" !
Acho que Oracle e Paradox tb devem usar ' ao invés de # para campos date time no SQL do ADO no VB 6.

É só ir testando na medida do possível.

http://www.vilmarbro.com.br

Página(s): 1/1

Seu Nome:
Seu eMail:		ALTERAR PARA MODO HTML
Mensagem: [:)] = [:P] = [:(] = [;)] = HTML DESLIGADO

VOLTAR