USUÁRIO:      SENHA:        SALVAR LOGIN ?    Adicione o VBWEB na sua lista de favoritos   Fale conosco 

 

  Dicas

  ASP - Active Server Page    (Miscelâneas)

Título da Dica:  Criar um sistema de rotação de banners de forma simples e sem ter de adquirir controlos
Postada em 9/10/2003 por ^HEAVY-METAL^            
O componente Adrotator é distribuído com as ASP desde a sua primeira versão.

Há três partes a considerar quando queremos implementar este componente:

1. Função para criar o banner com o seu respectivo link;
2. Ficheiro com os dados de todos os banners passíveis de aparecer;
3. Página de redirecionamento.

1. Função

Vamos criar primeiro a função que vai gerar a imagem do banner (com o respectivo link).

Podemos colocá-la diretamente numa ASP específica ou, por exemplo, num ficheiro que incluiremos em todas as ASP que quisermos através do comando "INCLUDE FILE".

Esta função vai fazer uso do ficheiro com os dados de todos os banners passíveis de aparecer.

O código será o seguinte:

<%
Function escolherBanner()

Dim PubBanner

' Criação de uma instância do componente Adrotator
Set PubBanner = Server.CreateObject("MSWC.AdRotator")

' Podemos definir para que Frame enviar o banner.
' Neste caso, o URL vai ser aberto numa janela nova
PubBanner.TargetFrame = "TARGET=new"

' Vamos indicar o ficheiro onde o componente irá escolher
' aleatóriamente o banner. Neste caso, o ficheiro encontra-se
' na mesma pasta da nossa ASP
escolherBanner = PubBanner.GetAdvertisement("./bnroda.txt")

End Function
%>

2. Ficheiro com os dados de todos os banners

Seguindo este exemplo, vamos criar o ficheiro "bnroda.txt". É este o ficheiro que conterá as referências de todos os banners a usar, bem como qual a freqüência com que serão mostrados.

Este ficheiro é constituído por duas partes, separadas por um único "*":

1. Informação aplicável a todas as imagens que serão "rodadas":

. REDIRECT - a página que vai tratar do redirecionamento;
. WIDTH - comprimento das imagens. Por omissão é 468;
. HEIGHT - altura das imagens. Por omissão é 60;
. BORDER - da imagem. Por omissão é 1.

2. Informação individual de cada imagem:

. Localização da imagem;
. URL para onde o utilizador é encaminhado quando clica neste;
. Descrição breve que surgirá nos Browsers que têm a opção de imagens desativada, ou que nem sequer as suportem;
. Freqüência com que será mostrado, em relação aos outros. Quanto mais alto o valor maior a freqüência. "0" indica que não é mostrado.

Terá de ser deixada uma linha de intervalo entre cada informação individual de imagem.

Arquivo bnroda.txt:

REDIRECT bnredir.asp
WIDTH 468
HEIGHT 60
BORDER 0
*
imgs/banner1.gif
http://www.site.com.br

Comunidade ASP portuguesa
3

imgs/banner2.gif
http://www.15seconds.com
Site de apoio a programadores ASP
2

3. Página de redirecionamento

A página de redirecionamento recebe na sua QueryString, uma variável "URL", que contém o URL para onde o utilizador será encaminhado, e uma variável "IMAGE" que contém o URL da imagem em que o utilizador clicou.

A única coisa que fazemos nesta página é receber o "URL" da QueryString e redirecionar para lá.

Arquivo bnredir.asp:

<%
' Activar o Response Buffer
Response.Buffer = True
Dim bannerURL
' Buscar o URL à QueryString
bannerURL = Request.QueryString("URL")
' Limpar o Response e redireccionar para o URL
Response.Clear()
Response.Redirect(bannerURL)
%>

Assim feito, só resta incluir a função na ASP onde queremos usar o sistema de banners. Depois, na página, poderemos chamar a função escolherBanner() em qualquer altura. Por exemplo:

<HTML>
<HEADER><TITLE>Exemplo de rotação de banners</TITLE></HEADER>
<BODY>
<!Vamos chamar um banner-->
<P><%=escolherBanner()%></P>
<BR>
<BR>
<BR>
<font face="Verdana">
Se formos fazendo 'Refresh' o banner é, aleatóriamente, alterado.
</font>
</BODY>
</HTML>

T+,
 


CyberWEB Network Ltda.    © Copyright 2000-2024   -   Todos os direitos reservados.
Powered by HostingZone - A melhor hospedagem para seu site
Topo da página